Use This Emulator!

https://www.calormen.com/jsbasic/

Copy This Code Into It!

Copy this code exactly how it is into the emulator, then press "Run"!

0000 HOME
0001 SPEED = 1
0002 NORMAL
0003 GOTO 22000
0010 GOSUB 1000
0020 GOSUB 2000
0030 GOSUB 3000
0099 REM ---- START ----
0100 GOSUB 4000
0110 GOSUB 6000
0120 GOSUB 7000
0130 GOSUB 8000
0140 GOSUB 9000
0996 IF L < 1 THEN GOTO 10000
0997 GOSUB 5000
0998 GOSUB 4000
0999 GOTO 0100
1000 REM ---- INITIALIZE ----
1010 NORMAL : HOME
1020 LET W = 64 : LET H = 32
1030 LET S = 0
1040 LET T = 1024
1050 LET HI = 0
1060 LET L = 3
1999 RETURN
2000 REM ---- INITIALIZE APPLE ----
2010 LET AX = 20 : LET AY = 1
2020 LET ALY = AY
2999 RETURN
3000 REM ---- INITIALIZE BASKET ----
3010 LET X = 20
3999 RETURN
4000 REM ---- INPUT ----
4010 LET K = PEEK(49152)
4020 IF K = 136 THEN X = 10
4030 IF K = 138 THEN X = 20
4040 IF K = 149 THEN X = 30
4050 RETURN
5000 REM ---- FRAME ----
5010 FOR N = 1 TO T : NEXT N
5015 NORMAL
5020 RETURN
6000 REM ---- RENDER APPLE ----
6010 HTAB AX : VTAB ALY
6020 PRINT (" ")
6030 HTAB AX : VTAB AY
6040 PRINT ("O")
6999 RETURN
7000 REM ---- RENDER BASKET ----
7010 IF X >< 10 THEN HTAB 10 : VTAB 23 : PRINT(" ")
7020 IF X >< 20 THEN HTAB 20 : VTAB 23 : PRINT(" ")
7030 IF X >< 30 THEN HTAB 30 : VTAB 23 : PRINT(" ")
7080 HTAB X : VTAB 23
7090 PRINT("U")
7999 RETURN
8000 REM ---- GRAVITY ----
8010 ALY = AY
8020 AY = AY + 1
8999 RETURN
9000 rem ---- COLLISION ----
9010 IF AY >< 23 THEN RETURN
9030 IF AX = X THEN S = S + 100 : NORMAL
9035 IF AX >< X THEN L = L - 1
9040 AY = 1
9045 T = T - 64 : IF T < 128 THEN T = 128
9050 LET RX = RND(1) : RX = RX * 10
9055 HOME
9060 HTAB 1 : VTAB 1 : PRINT("SCORE") : HTAB 7 : VTAB 1 : PRINT (S)
9065 HTAB 34 : VTAB 1 : PRINT("LIVES") : HTAB 40 : VTAB 1 : PRINT (L)
9070 IF RX < 3 THEN AX = 10 : RETURN
9080 IF RX >= 3 AND RX < 7 THEN AX = 20 : RETURN
9090 IF RX >= 7 THEN AX = 30 : RETURN
9999 RETURN
10000 REM ---- END GAME ----
10010 NORMAL
10015 HOME
10017 IF S <= HI THEN HTAB 16 : VTAB 2 : FLASH : PRINT ("TRY AGAIN") : NORMAL
10020 IF S > HI THEN HI = S : HTAB 14 : VTAB 2 : FLASH : PRINT ("NEW HIGHSCORE") : NORMAL
10030 HTAB 13 : VTAB 23 : PRINT ("MADE BY ELLIE :)")
10040 HTAB 14 : VTAB 8 : PRINT ("SCORE ") : HTAB 24 : VTAB 8 : PRINT (S)
10050 HTAB 14 : VTAB 12 : PRINT ("HIGHS ") : HTAB 24 : VTAB 12 : PRINT (HI)
10060 INVERSE : HTAB 16 : VTAB 20 : INPUT "CONTINUE?";C$
10070 NORMAL
10080 GOTO 21000
21000 REM ---- RESET ----
21010 S = 0
21020 T = 1024
21030 L = 3
21040 HOME
21050 GOTO 0099
22000 REM ---- TUTORIAL ----
22005 HTAB 15 : VTAB 4 : PRINT ("Apple Catcher")
22007 HTAB 1 : VTAB 5 : PRINT ("----------------------------------------")
22010 FLASH : HTAB 12 : VTAB 8 : PRINT ("ARROW KEYS TO MOVE") : NORMAL
22015 HTAB 13 : VTAB 12 : PRINT ("CATCH THE APPLES") : NORMAL
22020 INPUT "";C$
22030 GOTO 0010